Menghubungkan Sensor DHT11/22 dengan MCU-ESP32

Sensor DHT11/22 adalah sensor digital yang digunakan untuk mengukur suhu (temperature) dan kelembapan udara (humidity). Sensor ini menggunakan single-wire untuk berkomunikasi dengan mikrokontroler, sehingga memudahkan pengguna dalam berbagai proyek, seperti pengendalian sistem pemanas, ventilasi, dan pendingin udara yang dikenal sebagai heating, ventilation, and air conditioning (HVAC) system controlling.

Biasanya, sensor DHT11 berwarna biru, sedangkan DHT22 berwarna putih. Perbedaan utama antara DHT11 dan DHT22 terletak pada resolusi (ketelitian) dalam membaca suhu dan kelembapan udara di sekitarnya (ambient). DHT11 mampu membaca suhu antara 0°C hingga 50°C, sedangkan DHT22 dapat membaca suhu dalam kisaran -40°C hingga 80°C. Untuk kelembapan, DHT11 memiliki kisaran pembacaan 20% hingga 90% RH (Relative Humidity), sedangkan DHT22 dapat membaca kelembapan dari 0% hingga 100% RH.

Pinout Sensor DHT

Baik DHT11 maupun DHT22 memiliki pinout yang sama, seperti yang terlihat pada diagram pinout DHT11 berikut

Gambar Modul Sensor Diagram DHT11/22 Sumber electronicwings.com & etechnog.com

Pada dasarnya, DHT11/22 memiliki empat pin keluaran (pinout), tetapi satu pin tidak digunakan (Not Connected/NC) atau bahkan tidak ada sama sekali.

Pin VCC digunakan untuk menghidupkan sensor dengan tegangan masukan yang dapat diterima dari 3,3 V hingga 5 V. Pin DATA atau keluaran digunakan untuk berkomunikasi antara sensor dengan mikrokontroler. Biasanya, pin DATA ini dihubungkan dengan VCC melalui resistor tarik atas (pull-up resistor) (4,7 kΩ hingga 10 kΩ) untuk menstabilkan sinyal data, sedangkan pin GND terhubung ke ground untuk menyediakan tegangan referensi sebagai pelengkap rangkaian.

Wiring DHT11/22 Ke MCU-ESP32

Berikut ini adalah contoh skematik pengkabelan/wiring-diagram module sensor DHT11/22 dengan Mikrokontroler ESP-32 melalui Pin GPIO 13 (sesuaikan).

Gambar Modul Sensor Diagram DHT11/22 Sumber how2electronics.com

Pastikan saat menghubungkan module sensor DHT11/22 dengan ESP32 antara pin VCC dan GND tidak terbalik. Jika terbalik, maka module sensor DHT11/22 akan Short-circuit (arus pendek) yang dapat menyebabkan kerusakan pada modul sensor maupun pada mikrokontroler.

Code DHT11/22

Untuk membaca data modul sensor DHT11/22, dapat menggunakan pustaka/library dari Adafruit. Oleh karena itu, mula-mula kita install library teserbut dengan cara, membuka Arduin Ide, kemudian pada menu Sketch > Include Library > Manage Libraries, maka Library Manager akan terbuka. Selanjutnya pada pencarian/search, ketik kata kunci "DHT Sensor", pilih "DHT sensor library by Adafruit" dan klik Install.

Selanjutnya buka contoh program DHT11/22 dengan cara klik File > Examples > DHT sensor library> DHTtester. Berikut source-code untuk membaca modul DHT11 atau DHT22 ditulis melalui Arduino IDE.

// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:
// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library
// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 13     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 3 (on the right) of the sensor to GROUND (if your sensor has 3 pins)
// Connect pin 4 (on the right) of the sensor to GROUND and leave the pin 3 EMPTY (if your sensor has 4 pins)
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(115200);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) { 
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));
}

Bila ada diskusi/kendala, silahkan memberikan tanggapan pada kolom komentar dibawah, atau dapat mendiskusikannya dikelas atau di group perkuliahan bagi yang mengambil M.K terkait bersama saya.